rem ' colorchooser.txt
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
width = 450, height = 400
if info(6,0)="GWT" then width = 425, height = 300
window! = sysgui!.addWindow(100,100,width+50,height+100,"BBjColorChooser",$00090003$)
window!.setCallback(window!.ON_CLOSE,"eoj")
color! = bbjapi().makeColor(rnd(255),rnd(255),rnd(255))
chooser! = window!.addColorChooser(101,25,25,width,height,color!)
rem chooser!.setApproveButtonText("&Yes")
rem chooser!.setCancelButtonText("&No")
rem chooser!.setBackColor(bbjapi().makeColor(222,222,222))
chooser!.setCallback(chooser!.ON_COLORCHOOSER_CHANGE,"change")
chooser!.setCallback(chooser!.ON_COLORCHOOSER_APPROVE,"approve")
chooser!.setCallback(chooser!.ON_COLORCHOOSER_CANCEL,"cancel")
chooser!.setCallback(chooser!.ON_GAINED_FOCUS,"event")
chooser!.setCallback(chooser!.ON_LOST_FOCUS,"event")
chooser!.setCallback(chooser!.ON_MOUSE_ENTER,"event")
chooser!.setCallback(chooser!.ON_MOUSE_EXIT,"event")
chooser!.setCallback(chooser!.ON_POPUP_REQUEST,"event")
chooser!.setCallback(chooser!.ON_RIGHT_MOUSE_DOWN,"event")
button! = window!.addButton(1,width+25-80,height+50,80,21,"Set Color",$$)
button!.setCallback(button!.ON_BUTTON_PUSH,"color")
process_events
eoj:
  release
color:
  color! = bbjapi().makeColor(rnd(255),rnd(255),rnd(255))
  chooser!.setColor(color!)
return
change:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$,": ",event!.getColor()
return
approve:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$,": ",event!.getColor()
return
cancel:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$
return
event:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  control! = event!.getControl()
  control$ = control!.toString(), control$ = control$(1,pos("@"=control$)-1)
  print control$," ",event$
return