rem ' progressbar.txt
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(100,100,300,115,"BBjProgressBar",$2009008f$)
window!.setCallback(sysgui!.ON_CLOSE,"eoj")
startButton! = window!.addButton(1,5,10,90,25,"Start")
stopButton! = window!.addButton(2,105,10,90,25,"Stop",$0001$)
stopButton!.setCallback(sysgui!.ON_BUTTON_PUSH,"doStop")
startButton!.setCallback(sysgui!.ON_BUTTON_PUSH,"doStart")
resetButton! = window!.addButton(3,205,10,90,25,"Reset")
resetButton!.setCallback(sysgui!.ON_BUTTON_PUSH,"doReset")
ProgressBar! = window!.addProgressBar(101,5,45,290,25)
ProgressBar!.setCallback(ProgressBar!.ON_GAINED_FOCUS,"event")
ProgressBar!.setCallback(ProgressBar!.ON_LOST_FOCUS,"event")
ProgressBar!.setCallback(ProgressBar!.ON_MOUSE_ENTER,"event")
ProgressBar!.setCallback(ProgressBar!.ON_MOUSE_EXIT,"event")
ProgressBar!.setCallback(ProgressBar!.ON_POPUP_REQUEST,"event")
ProgressBar!.setCallback(ProgressBar!.ON_RIGHT_MOUSE_DOWN,"event")
indeterminate! = window!.addCheckBox(102,5,80,120,25,"Indeterminate",$$)
indeterminate!.setCallback(indeterminate!.ON_CHECK_ON,"indeterminateOn")
indeterminate!.setCallback(indeterminate!.ON_CHECK_OFF,"indeterminateOff")
process_events
eoj:
  release
doStart:
  startButton!.setEnabled(0)
  bbjapi().createTimer("progress-timer",1.0,"progress")
  stopButton!.setEnabled(1)
  return
doStop:
  stopButton!.setEnabled(0)
  bbjapi().removeTimer("progress-timer")
  startButton!.setEnabled(1)
return
progress:
  ProgressBar!.setValue(ProgressBar!.getValue()+10)
  if ProgressBar!.getValue() >= ProgressBar!.getMaximum()
     gosub doStop
  endif
return
doReset:
  ProgressBar!.setValue(ProgressBar!.getMinimum())
return
indeterminateOn:
  ProgressBar!.setIndeterminate(1)
  ProgressBar!.setText("Your call is important to us...")
  ProgressBar!.setStringPainted(1)
return
indeterminateOff:
  ProgressBar!.setIndeterminate(0)
return
event:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  control! = event!.getControl()
  control$ = control!.toString(), control$ = control$(1,pos("@"=control$)-1)
  print control$," ",event$
return