rem ' clientfilechooser.txt
if msgbox("FILEOPEN or FILESAVE?",7+32,"Client File Chooser","FILEOPEN","FILESAVE")=1 then
   flags$ = $0004$
   title$ = "Client FILEOPEN"
else
   flags$ = $0104$
   title$ = "Client FILESAVE"
endif
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
tc! = bbjapi().getThinClient()
fs! = tc!.getClientFileSystem()
x = 100, y = 100, width = 400, height = 300
if info(6,0)="GWT" then x = 20, y = 20, height = 150
window! = sysgui!.addWindow(x,y,width+50,height+50,title$,$00090003$)
window!.setCallback(window!.ON_CLOSE,"eoj")
directory$ = ""
chooser! = window!.addFileChooser(101,25,25,width,height,directory$,flags$)
chooser!.setMultiSelectionEnabled(1)
chooser!.addFileFilter("Text files","*.txt")
vector! = bbjapi().makeVector()
vector!.add("*.png")
vector!.add("*.gif")
vector!.add("*.bmp")
vector!.add("*.jpg")
chooser!.addFileFilter("Image files",vector!)
rem chooser!.setApproveButtonText("&Yes")
rem chooser!.setCancelButtonText("&No")
rem chooser!.setBackColor(bbjapi().makeColor(227,232,243))
chooser!.setCallback(chooser!.ON_FILECHOOSER_CHANGE,"change")
chooser!.setCallback(chooser!.ON_FILECHOOSER_APPROVE,"approve")
chooser!.setCallback(chooser!.ON_FILECHOOSER_CANCEL,"cancel")
chooser!.setCallback(chooser!.ON_GAINED_FOCUS,"event")
chooser!.setCallback(chooser!.ON_LOST_FOCUS,"event")
chooser!.setCallback(chooser!.ON_MOUSE_ENTER,"event")
chooser!.setCallback(chooser!.ON_MOUSE_EXIT,"event")
chooser!.setCallback(chooser!.ON_POPUP_REQUEST,"event")
chooser!.setCallback(chooser!.ON_RIGHT_MOUSE_DOWN,"event")
process_events
eoj:
  release
change:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$,": ",event!.getSelectedFiles()
  i = msgbox(event$ + ": " + str(event!.getSelectedFiles()))
return
approve:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$,": ",event!.getSelectedFiles()
  i = msgbox(event$ + ": " + str(event!.getSelectedFiles()))
  rem ' erase the temporary copy of that file from the server
  for i = 0 to event!.getSelectedFiles().size()-1
    clientfile$ = event!.getSelectedFiles().get(i)
    clientfile! = fs!.getClientFile(clientfile$)
    if info(6,0)="GWT" then clientfile!.delete()
  next i
return
cancel:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  print event$
  i = msgbox(event$)
return
event:
  event! = sysgui!.getLastEvent()
  event$ = event!.toString(), event$ = event$(1,pos("@"=event$)-1)
  control! = event!.getControl()
  control$ = control!.toString(), control$ = control$(1,pos("@"=control$)-1)
  print control$," ",event$
return